plugins {
    id 'com.android.application'
    id 'org.jetbrains.kotlin.android'
    id 'org.jetbrains.kotlin.plugin.serialization'
}

android {
    namespace 'app.myzel394.alibi'
    compileSdk 34

    def keystoreProperties = new Properties()
    def keystorePropertiesFile = rootProject.file('key.properties')
    if (keystorePropertiesFile.exists()) {
        keystoreProperties.load(new FileInputStream(keystorePropertiesFile))
    }

    lint {
        disable "ExtraTranslation"
    }

    androidResources {
        generateLocaleConfig = true
    }

    splits {
        abi {
            enable true

            universalApk true
        }
    }

    defaultConfig {
        multiDexEnabled true
        applicationId "app.myzel394.alibi"
        minSdk 24
        targetSdk 34
        versionCode 16
        versionName "0.5.3"

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
        vectorDrawables {
            useSupportLibrary true
        }
    }

    signingConfigs {
        release {
            keyAlias keystoreProperties['keyAlias']
            keyPassword keystoreProperties['keyPassword']
            storeFile keystoreProperties['storeFile'] ? file(keystoreProperties['storeFile']) : null
            storePassword keystoreProperties['storePassword']
        }
    }

    buildTypes {
        release {
            signingConfig signingConfigs.release

            debuggable false
            minifyEnabled true
            shrinkResources true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
        debug {
            applicationIdSuffix ".debug"
            debuggable true
        }
    }
    compileOptions {
        coreLibraryDesugaringEnabled true
        // Sets Java compatibility to Java 8
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
    kotlinOptions {
        jvmTarget = '1.8'
    }
    buildFeatures {
        compose true
        buildConfig = true
        viewBinding = true
    }
    composeOptions {
        kotlinCompilerExtensionVersion '1.5.10'
    }
    packagingOptions {
        resources {
            excludes += '/META-INF/{AL2.0,LGPL2.1}'
        }
    }
}

dependencies {
    implementation 'androidx.core:core-ktx:1.13.1'
    implementation platform('org.jetbrains.kotlin:kotlin-bom:1.8.0')
    implementation 'androidx.lifecycle:lifecycle-runtime-ktx:2.8.4'
    implementation 'androidx.activity:activity-compose:1.9.1'
    implementation 'androidx.activity:activity-ktx:1.9.1'
    implementation platform('androidx.compose:compose-bom:2024.09.00')
    implementation 'androidx.compose.ui:ui'
    implementation 'androidx.compose.ui:ui-graphics'
    implementation 'androidx.compose.ui:ui-tooling-preview'
    implementation 'androidx.compose.material3:material3:1.2.1'
    implementation "androidx.compose.material:material-icons-extended:1.6.8"
    implementation 'androidx.appcompat:appcompat:1.7.0'
    implementation 'androidx.documentfile:documentfile:1.0.1'
    implementation 'androidx.lifecycle:lifecycle-service:2.8.4'

    testImplementation 'junit:junit:4.13.2'
    androidTestImplementation 'androidx.test.ext:junit:1.2.1'
    androidTestImplementation 'androidx.test.espresso:espresso-core:3.6.1'
    androidTestImplementation platform('androidx.compose:compose-bom:2024.09.00')
    androidTestImplementation 'androidx.compose.ui:ui-test-junit4'
    debugImplementation 'androidx.compose.ui:ui-tooling'
    debugImplementation 'androidx.compose.ui:ui-test-manifest'

    implementation "androidx.navigation:navigation-compose:2.7.7"

    implementation 'com.google.dagger:hilt-android:2.49'
    annotationProcessor 'com.google.dagger:hilt-compiler:2.49'
    implementation "androidx.hilt:hilt-navigation-compose:1.2.0"

    coreLibraryDesugaring 'com.android.tools:desugar_jdk_libs:2.1.1'

    implementation 'com.arthenica:ffmpeg-kit-full-gpl:5.1'

    implementation "androidx.datastore:datastore-preferences:1.1.1"

    implementation "org.jetbrains.kotlinx:kotlinx-serialization-json:1.5.1"


    implementation 'com.maxkeppeler.sheets-compose-dialogs:core:1.2.0'
    implementation 'com.maxkeppeler.sheets-compose-dialogs:duration:1.2.0'
    implementation 'com.maxkeppeler.sheets-compose-dialogs:list:1.2.0'
    implementation 'com.maxkeppeler.sheets-compose-dialogs:input:1.2.0'

    def camerax_version = "1.3.4"
    implementation "androidx.camera:camera-core:${camerax_version}"
    implementation "androidx.camera:camera-camera2:${camerax_version}"
    implementation "androidx.camera:camera-lifecycle:${camerax_version}"
    implementation "androidx.camera:camera-video:${camerax_version}"

    implementation "androidx.camera:camera-view:${camerax_version}"
    implementation "androidx.camera:camera-extensions:${camerax_version}"


    implementation "com.valentinilk.shimmer:compose-shimmer:1.2.0"

    implementation "androidx.biometric:biometric-ktx:1.2.0-alpha05"
}